Zwei rekursive Funktionen

Zwei rekursive Funktionen

Rekursiver Baum und Drachenkurve

Rekursiver Baum:
Angeregt von der Grafik auf der vorletzten Seite des Begleitmaterials zum BasiCode-Lehrgang im Rundfunk der DDR.

Im Begleitmaterial zum BasiCode-Lehrgang des DDR Rundfunks ist auf der vorletzten Seite eine Grafik abgedruckt, zu der es aber keine Erklärung gibt. Mich hatte schon länger interessiert, wie sie erzeugt wurde, daher suchte ich im Internet, fand sogar ein Programm - doch in LOGO. Dann fragte ich im Robotrontechnik-Forum nach und wenig später postete jemand ein Programm.

Dieses habe ich für BasiCode angepasst:

1000 A=100:GOTO 20: REM ## REKURSIVER BAUM ##
1010 CN=0 :CC(0)=0 :CC(1)=7 :GOSUB 600
1020 P1=3.14159265 :MX=330 :MD=8
1030 DIM X(MX),Y(MX),D(MX),A(MX),L(MX) :TP=0
1040 X(0)=100 :Y(0)=0 : D(0)=0 :A(0)=P1/2 :L(0)=52
1050 IF TP<0 THEN 1200
1060 X1=X(TP) :Y1=Y(TP) :D1=D(TP)
1070 A1=A(TP) :L1=L(TP)
1080 TP=TP-1
1090 X2=X1+L1*COS(A1)
1100 Y2=Y1+L1*SIN(A1)
1110 CC(0)=4: IF D16 THEN CC(0)=2
1120 HO=X1/HG :VE=1-Y1/VG :GOSUB 620
1125 HO=X2/HG :VE=1-Y2/VG :GOSUB 630
1130 IF D1>=MD THEN 1050
1140 D2=D1+1
1150 TP=TP+1
1160 X(TP)=X2 :Y(TP)=Y2 :D(TP)=D2 :A(TP)=A1-.33
1165 L(TP)=L1*.88
1170 TP=TP+1
1180 X(TP)=X2 :Y(TP)=Y2 : D(TP)=D2 :A(TP)=A1+.68
1185 L(TP)=L1*.5
1190 GOTO 1050
1200 GOSUB 210
1210 GOSUB 100 :GOTO 950
32000 REM #####################################
32010 REM #                                   #
32020 REM #         Rekursiver Baum           #
32030 REM #      angeregt von der Grafik      #
32040 REM #     auf der vorletzten Seite      #
32050 REM #     des Begleitmaterials zum      #
32060 REM #         BasiCode-Lehrgang         #
32070 REM #        im Rundfunk der DDR        #
32080 REM #                                   #
32090 REM # programmiert fuer BIC A5105 von:  #
32100 REM # Cornelius (Robotrontechnik-Forum) #
32110 REM #                                   #
32120 REM #        BasiCode-Anpassung:        #
32130 REM #         Thomas Rademacher         #
32140 REM #         JOYCE-User-AG e.V.        #
32150 REM #                                   #
32160 REM #             April 2026            #
32170 REM #                                   #
32180 REM #####################################

Unsere Joyce brauchte wieder eine Sonderbehandlung: Das Listing wird als normales Basic-Programm unter Mallard Basic gestartet; es enthält den (modifizierten) Bascoder, so dass dieser nicht vor-gelanden werden muss.

Damit die Grafik nicht horizontal gestaucht erscheint, nahm ich eine kleine Änderung vor:

Im übertragbaren Teil des rekursiver-Baum-Programms wird vor GOSUB 620 (Setzen eines Punkts) und GOSUB 630 (Zeichnen einer Linie) bei der Zuweisung von HO statt X1/HG 2*X1/HG verwendet, um das gleiche Breite-Höhe-Verhältnis wie auf anderen Computern zu erhalten:

1120 HO=2*X1/HG :VE=1-Y1/VG :GOSUB 620
1125 HO=2*X2/HG :VE=1-Y2/VG :GOSUB 630

Außerdem dient (in beiden Programmen) im Bascoderteil die zweimalige Ergänzung "+.001" dem leichten Versatz der Höhe der Zeichnung nach oben, sonst entstehen durch Rundungsungenauigkeiten teilweise dicker erscheinende horizontale Linien:

655 OHO=MAX(0,HO):OHO=MIN(OHO,0.998):OVE=MAX(0,VE)+0.001:OVE=MIN(OVE,0.995)+0.001:RETURN

Drachenkurve:
Programm aus dem Buch "In BASIC effektiv programmieren - Auch mit Kleinstrechnern" von Horst Völz.

Bei der Suche fand ich in einem DDR-Computerbuch ein weiteres interessantes Programm, es zeichnet die "Drachenkurve". Sie ähnelt vom Prinzip der Peano- und der Hilbert-Kurve: Kleine Strukturen wiederholen sich in den größeren. Es hat, finde ich, eine gewisse Faszination, beim Zeichnen zuzuschauen - sofern der Computer langsam genug ist und die Grafik nicht "in einem Rutsch" auf dem Bildschirm erscheint, wie zum Beispiel unter BBC Basic for Windows.

Auch wieder mit Rekursion:

1000 A=100: GOTO 20: REM DRACHENKURVE
1010 GOSUB 100: HO=13: VE=0: CN=0: GOSUB 110
1410 PRINT "## DRAGON ##": PRINT: GOTO 1460
1420 IF L<>0 THEN 1430
1425 HO=(X+A)/HG: VE=1-(Y+B)/VG: GOSUB 630: X=X+A: Y=Y+B: RETURN
1430 L=L-1: GOSUB 1420: C=A: A=-B: B=C: GOSUB 1440: L=L+1
1435 RETURN
1440 IF L<>0 THEN 1450
1445 HO=(X+A)/HG: VE=1-(Y+B)/VG: GOSUB 630: X=X+A: Y=Y+B: RETURN
1450 L=L-1: GOSUB 1420: C=A: A=B: B=-C: GOSUB 1440: L=L+1
1455 RETURN
1460 INPUT"Zahl =";L: GOSUB 600: X=HG/2: Y=50
1465 HO=X/HG: VE=1-Y/VG: GOSUB 620: A=0: B=-2 :GOSUB 1420
1470 GOSUB 210: GOTO 950
32000 REM #####################################
32010 REM #                                   #
32020 REM #          Drachenkurve             #
32030 REM #                                   #
32040 REM #      Programm aus dem Buch        #
32050 REM # "In BASIC effektiv programmieren  #
32060 REM #     Auch mit Kleinstrechnern"     #
32070 REM #          von Horst Voelz          #
32080 REM #                                   #
32090 REM #        BasiCode-Anpassung:        #
32100 REM #         Thomas Rademacher         #
32110 REM #         JOYCE-User-AG e.V.        #
32120 REM #                                   #
32130 REM #             April 2026            #
32140 REM #                                   #
32150 REM #####################################

Und auch wieder "normales" BasiCode und PCW-spezifisch (das Programm beinhaltet den angepassten Bascoder und wird als normales Basic-Programm unter Mallard Basic gestartet; der Bascoder muss nicht vor-gelanden werden).

Im übertragbaren Teil des Drachenkurve-Programms wird vor GOSUB 630 (Zeichnen einer Linie) bei der Zuweisung von HO statt (X+A) (X+2*A) verwendet, um das gleiche Breite-Höhe-Verhältnis wie auf anderen Computern zu erhalten:

1425 HO=(X+2*A)/HG+0.2: VE=1-(Y+B)/VG: GOSUB 630: X=X+2*A: Y=Y+B: RETURN
1445 HO=(X+2*A)/HG+0.2: VE=1-(Y+B)/VG: GOSUB 630: X=X+2*A: Y=Y+B: RETURN

Außerdem dient (wie auch beim rekursiver-Baum-Programm) im Bascoderteil die zweimalige Ergänzung "+.001" dem leichten Versatz der Höhe der Zeichnung nach oben, sonst entstehen durch Rundungsungenauigkeiten teilweise dicker erscheinende horizontale Linien:

655 OHO=MAX(0,HO):OHO=MIN(OHO,0.998):OVE=MAX(0,VE)+0.001:OVE=MIN(OVE,0.995)+0.001:RETURN

Nach dem Programmstart wird man aufgefordert eine natürliche Zahl > 0 einzugeben; diese Zahl gibt an, wie oft die Rekursion ausgeführt werden soll, d.h. wie hoch die Verschachtelungstiefe ist. Die Gesamtkurve wird durch die selbstähnliche Wiederholung immer größer, irgendwann reicht die Breite und Höhe der Zeichenfläche nicht mehr aus, wie man durch Probieren leicht erkennen kann.

Thomas Rademacher // April 2026